SegmentNextSkyrim Console Commands - Skyrim Console Cheats, PC Console Commands
The Skyrim Console Commands can be accessed in-game by pressing the ’tilde key’, found near the ‘1’ key on the most keyboards. It is not case-sensitive and the console prompt will appear in the lower left-hand corner of the screen. You can scroll the console output using the ‘Page Up’ and ‘Page Down’ keys.
These Skyrim commands can allow you to access the otherwise inaccessible features, make changes to AI, enable God mode, and so much more. You can use these Skyrim PC Cheats to become the all-powerful Dragonborn and do whatever you please.
For more help on Skyrim, read our Tweaks Guide and Crashes, Freezes, and Fixes Guide
Skyrim Console Commands and Item Codes
There are plenty of Skyrim PC commands that you can use to unlock God mode, steal without getting caught, and so much more. As mentioned earlier, you can insert Skyrim commands after pressing the ‘tilde key’ on your keyboard. Doing so should allow you to open up a menu that should allow you different Skyrim PC cheats, activating/deactivating plenty of settings.
In this Skyrim Commands and Item Codes Guide, we have detailed everything you need to know about different Skyrim PC commands, their in-game effects, and more.
Toggle Commands
These Skyrim PC console commands will toggle on/off the different settings in The Elder Scrolls V: Skyrim.
| Command | Effect |
| rm | You can use this command to toggle Run Mode. This will let you switch between run and walking mode and performs the same function as <Caps Lock> key. |
| tai | This command is used to toggle Artificial Intelligence (Characters will not react to non-combat stimuli and dialogue may not function. Used in conjunction with TCAI will completely disable NPC actions.) |
| tc | Control of target entity of the player will toggle using this command. If you use this while targeting an NPC then it will transfer control to said NPC, and any command inputs will be applied both characters. To fix, use TC on the Dragonborn to turn off their actions. |
| tcai | This will toggle Combat Artificial Intelligence (Characters may turn hostile but will not attack the Dragonborn.) |
| tcl | You can toggle Collision using this command. Using the TCL command with a target toggles clipping for the target. If used while falling off a cliff, may cause a crash. Useful for relocating the Dragonborn or finding items or bodies that have fallen through a wall or floor. |
| tdetect | This will toggle AI Detection. Does not work with Pickpocket detection. |
| teofis | This will toggle relatively taxing image settings such as blur. May result in an increase in frames per second. |
| tfc | This will toggle freefly camera. Add <1> to pause. |
| tfow | This will toggle regions on the local map. i.e. loads all unexplored areas on the local map. |
| tg | This toggles grass. |
| tgm | This will toggle God Mode (Grants infinite health, magicka, and stamina. Carry weight will never affect movement or fast travel.) |
| tim | This will toggle Immortal Mode (Character will still take damage, but their health will never reach zero. Final blow animations may cause a permanent decapitation bug.) |
| tll | Toggles LOD |
| tm | Toggle Menus (Disables all GUI elements, including menus, the compass, subtitles and messages. Very useful for taking screenshots.) |
| tmm <#> | Toggle Map Markers; <0> Disable all. <1> Enable all. <1,0,1> Show all, no fast travel. |
| ts | Toggles display of skybox and fog. |
| tscr | Toggles script processing |
| tt | Toggles trees |
| twf | Toggles framework border |
| tws | Toggle water display when not underwater |
Targeted Commands
| Command | Effect |
| additem <ItemID> <#> | Adds <ItemID> to target NPC, Note: Use on a merchant to set the amount of barter gold. This gold will not go to the Dragonborn’s inventory when selling items to the vendor if the additem causes the vendor’s gold to exceed 32,767, the maximum positive number that can be stored in an int variable in C. To avoid this, increment by 32,700 less the merchant’s current gold, sell items and repeat as needed. If it does go over, using additem with a negative number can fix this, for example, “additem f -10000” |
| DamageActorValue <attribute> <amount> | Lowers the given attribute by the desired amount. |
| Disable | This will make the target disappear, but still loaded with the cell (see also: MarkForDelete). |
| Dispelallspells | Removes spell effects such as poisons from the target. |
| duplicateallitems <refID> | After targeting an NPC, this can be used to place a copy of their inventory into that of another NPC. |
| Enable | Used to make disabled targets re-appear. |
| equipitem <ItemID> <#><left/right> | Forces the target to equip <ItemID>, if it is in their inventory. Adding a “1” after the ID seems to make some items un-removable, while “0” keeps them removable as normal. <left/right> will equip the weapon in the left or right hand. |
| equipspell <SpellID> <left/right> | Forces the target to equip <SpellID>, <left/right> will equip the spell in the left or right hand. Spells cannot be acquired by addspell command such as Vampiric Drain can be acquired temporarily in this way. As for player variant: type “player.Equipspell <SpellID> <left/right>” |
| forceav <AV> <#> | Forces <AV> to <#> |
| GetAngle <axis> | Returns the value of given rotational axis (x,y,z) of the target. |
| getav <AV> | Returns the current value of the specified actor value. |
| getavinfo <AV> | Returns info about the specified actor value. |
| Getlevel | Returns the level of the target. |
| getlocationcleared <ID> | Returns the clear code off the specified location. Requires the numerical location ID. |
| getpos <axis> | Returns the position value of given axis (x,y,z) of the target |
| getrelationshiprank <ID> | Returns the numerical rank of the friendliness between two characters (-4–4). |
| hasperk <ID> | Returns whether or not the target has the specified perk. |
| Kill | Instantly kills target. (Does not kill characters/creatures marked “essential,” only causes them to fall to the ground for a few minutes.) |
| lock <#> | Lock chests, doors or people. <#> = the level of difficulty. (0–100, any larger and the lock cannot be picked) |
| MarkForDelete | Permanently deletes the selected item either instantaneously or upon reload. This command is cleaner than disable, as it removes the item completely instead of hiding it from view. |
| modav <AV> <+/-#> | Changes <AV> by <+/-#> |
| moveto player | Teleports the targeted NPC to the Dragonborn. (Works similar to player.placeatme <BaseID> <#> but does not create a new reference of the base object.) |
| openactorcontainer <#> | <#> = 1, 2, 3, or 4. Depending on the actors faction ranking to the Dragonborn will depend on what is seen in their inventory. Use the correct ranking for their current status. This allows one to add or retrieve items from that actor. Some actors will not equip armor or weapons stored on them. |
| playidle <ID> | Makes the target do the specified action, such as a specific attack animation. |
| pushactoraway <ID> <distance> | Attract or repel the target in relation to the Dragonborn by the specified amount. |
| Recycleactor | Cycle between different actors within the same actor ID randomly. |
| Removeallitems | Removes all items in the targets inventory. Use the <player> variable to transfer all items to own inventory. |
| Resetai | Resets the AI of the target (see also: tai). |
| Resetinventory | Restores the target’s inventory to its original state. |
| RestoreActorValue <attribute> <amount> | Reverses the effect(s) of DamageActorValue. |
| resurrect <#> | Return a dead NPC to life. Replace <#> with 1 to resurrect with all current items intact. Leave off <#> to have the corpse removed & a new copy spawned. |
| setactoralpha <#> | Changes the transparency of the target. Ranges are in decimal from 0–1, with 0 being completely invisible, 0.5 being half visible and 1 being completely visible. |
| SetAngle <axis> <#> | Sets the value of given rotational axis (x,y,z) of the target (the change happens when the targeted object is picked up). |
| setav <AV> <#> | Like forceav, but some values do not stay set through saves. |
| setcellownership <LocationID> | Marks desired interior or exterior cell as owned by the player, as well as everything within its perimeter. |
| setessential <BaseID> <#> | Make NPC mortal (0) / immortal(1). |
| setfavorstate <#> | 0 = inactive, 1 = active. Makes any targeted NPC obey player commands by moving the cursor over an interactable object or NPC while activated. In example, typing setfavorstate 1 while having a Guard selected in the command console and clicking on a dropped item, makes that Guard pick-up and automatically equip that item. After issueing a command, typing setfavorstate 0 while a command has not yet been issued or pressed the TAB button will cancel and deactivate the command. |
| setghost <#> | Makes the target either intangible or susceptible to damage or staggering effects. Range of 0-1, with 0 making the target tangible, and 1 making the target intangible. |
| setgs <attribute> <amount> | Set Game Setting. |
| setlevel <1>,<2>,<3>,<4> | Sets the level of an NPC compared to the Dragonborn. SetLevel 1000,0,1,81 will make target level with the Dragonborn from 1 to 81. 1: <% of PC’s level * 10> The NPC’s level in comparison to the Dragonborn, based on % of their level. (1000 = 100.0%) 2: <1 level +/-> How many levels this NPC will be above or below the level in 1. 3: <starting level> The lowest level this NPC can be. 4: <level cap> The highest level this NPC can be. |
| setlocationcleared <ID> <#> | Sets a location as cleared (1) or uncleared (0). The numerical location ID must be used. |
| setnpcweight <#> | Sets the weight of the target or the Dragonborn. Ranges from 0–100, with 0 being the lightest and 100 being the heaviest. |
| setownership <BaseID> | Allows one to make items owned by different people. They will not become the Dragonborn’s unless an ID is not entered. When used on chests, applies to everything inside. |
| SetPos <axis> <#> | Sets the position value of given axis (x,y,z) of the target. |
| setrelationshiprank <refID> <#> | Used to set an NPCs disposition towards the Dragonborn. <#> = 1–4 Note: If this does not help when attempting to add Follower dialogue, use setrelationshiprank <refID> <#> then player.setrelationshiprank <refID> <#>. |
| setscale <#> | Sets the scale of an object. “1” is default. If no object is selected, applies to PC. NOTE: When used on an actor, it increases or decreases speed and damage. Also note that the lowest possible value to change the scale, is 0.1, and the highest possible value to change the scale, is 10.00, exactly on the dot. |
| setunconscious <#> | Sets the target as unconscious. Range of 0–1, with 0 being conscious and 1 being unconscious. |
| Sexchange | Change gender of target NPC, or PC. Note: Only BODY changes, not the head. |
| shp <#> | Set HDR Parameter. Nine separate numbers should be entered to change various luminosity settings. |
| sifh <#> | Set Ignore Friendly Hit. Range of 0–1, with 0 causing the target not to ignore friendly hits and 1 causing the target to ignore them. |
| str <#> | Set Target Refraction. Range of 0–1, with0.000001 being completely invisible and 1.000000 being completely visible, and 0 reverting the target to its default state. |
| unequipitem <ItemID> <#><left/right> | Forces the target to unequip <ItemID>, similar to the Equipitem command except it unequips items if it is in one’s inventory. Adding a ‘1’ after the ID will make certain items unable to be removed, while ‘0’ keeps them removable as normal. <left/right> will unequip the weapon in the left or right hand. |
| Unlock | Unlock the desired chest or door. Note: This may not work in some cases. |
Quest Commands
| Command | Effect |
| Caqs | Complete all Stages of EVERY quest. Buggy, may not be stable. NOT recommended. |
| completequest <QuestID> | Complete a quest. May cause buggy behavior, SetStage is generally cleaner. |
| getstage <QuestID> | Used to get the current quest stage for quest (use ShowQuestTargets for IDs). |
| movetoqt <QuestID> | Move to quest target. |
| player.sqs <quest id> | Used to display all the stages of a quest |
| resetquest <QuestID> | Completely resets the given quest. |
| Saq | Starts every quest. (May cause crash) |
| SetObjectiveCompleted <QuestID> <stage> <1 to set, 0 to unset> | Used to set the quest stage as being completed or uncompleted. |
| setpqv <quest form ID> <quest variable ID> <desired variable> | Attempts to modify a quest variable to the desired value. |
| setstage <quest id> <stage value> | Used to set the quest stage (Useful for bugged quests). |
| Showquesttargets | Shows all current quest IDs. |
| sqv <quest id> | Displays a list of all variables used by <quest id>. |
Player Commands
| Command | Effect |
| Addshout <ShoutID> | Add shout to one’s skill list. Shouts are also part of spells, so in order for this command to work the spells will need to already be unlocked. List of Shout Codes. NOTE: Shouts can be unlocked using: player.unlockword <shoutID> |
| AdvSkill <AV> <#> | Gives one the desired amount of skill usage points. NOTE: Very inconsistent between skills. E.g. “AdvSkill speechcraft 3000” gives about as much Speech experience as “AdvSkill enchanting 1” gives Enchanting experience. See skills for test results. |
| Animcam | Allows for the camera to view the Dragonborn from any direction without changing which way they are facing. |
| Enableplayercontrols | This command is used to enable controls during cinematics when they are disabled. Occasionally the game will glitch, instead of reloading put in this command and carry on. |
| fov <#> | Adjust field of view. The default is 75, and the maximum value appears to be 160. Higher numbers allow a wider field of vision, but it can be distorted. Lower numbers show a “zoomed” view. 60–90 is a useful range. |
| IncPCS <AVskill> | Increase the Dragonborn’s skill points by one point. For example, the command IncPCS marksman will raise the Archery skill by 1. |
| player.additem <ItemID> <#> | Add an item to the inventory. For example, to add 100 gold to the inventory, use player.additem f 100 |
| player.addperk <PerkID> | Adds the perk. |
| player.addspell <variable> | Adds a spell, disease, or power. This can also be used for acquiring an unused spell. ex: Conjure Dragon Priest, does not work for vampiric spells. |
| player.advlevel | Force a Level Up (Does not add ability to pick a new perk). |
| player.drop <ItemID> <#> | This will drop the item. |
| player.forceav <AV> <#> | Should be avoided for use, as it overrides game’s automatic calculations such as item bonuses, spell bonuses, etc. |
| player.forceav dragonsouls # | Sets the number of Dragon Souls the Dragonborn has. Replace # with the desired number. |
| player.modav <AV> <+/-#> | Modifies the Actor Value by <#>. |
| player.paycrimegold <X> <Y> <FactionID> | On occasion, this may not pay off the entire bounty X = 1 Remove stolen items. 0 Do not remove stolen items. Y = 1 Go to jail. 0 Do not go to jail. |
| player.placeatme <Item/NPCID> <#> | Places an item or actor next to the Dragonborn. |
| player.removeitem <ItemID> <#> | Remove an item from the inventory. |
| player.removeperk <PerkID> | Removes a perk.; does not return the point used to gain the perk. |
| player.removespell <variable> | Removes a spell, disease, or power. |
| player.resethealth | Refills the Dragonborn’s health instantly. |
| player.setav <AV> <#> | Sets the Actor Value to <#>. |
| player.setcrimegold <#> <FactionID> | Adds <#> to one’s current bounty with <FactionID> |
| player.setlevel <#> | Sets current level to <#>. |
| Player.SetRace <RaceID> | A variant of SetPlayerRace <Raceid>, it is possible to become non-human race using this variant i.e. Player.SetRace DragonRace will transform the Dragonborn into a Dragon and capable of using Thu’um under Dragon voice clip, this variant can also be used on NPCs. |
| player.setscale # | Sets height for character. Tsun, for example, ranks 1.23 on the height scale. |
| player.showinventory | Lists all items in the Dragonborn’s inventory and their codes. PgUp and PgDwn to scroll through. |
| player.teachword <WOOP> | Teaches a word of power, words can be found with the “help <word> 4” command and are recognizable by the WOOP tag. See Dragon Shouts. |
| player.unlockword <shoutID> | Unlocks a word of power. List of Shout Codes. |
| playerEnchantObject <ItemID> <mgef> <mgef> | Adds object to inventory with any two magic effects (not limited to enchants). Codes |
| Psb | Player Spell Book. Unlocks all spells and shouts. NOTE: Using this command will unlock every spell, even those used to test Skyrim. However, this may cause bugs. |
| s1st | While in third person, the Dragonborn’s arms, which would normally only appear in first person, appear behind them, allowing for the Dragonborn to experience first person and third person simultaneously. |
| SetPlayerRace <Raceid> | Doing this will allow the Dragonborn’s race to be changed without using showracemenu. Note: May bug after certain transformations (ex: Werewolf), and revert to original race, or the race that was selected using showracemenu. |
| Showracemenu | Bring up character customization menu. Magicka, Stamina, and Health will be spread evenly on using this depending on one’s character’s level. It will remove any custom point distributions. Note: Using TGM command before entering the menu will retain the original levels. Will only modify one’s attributes/skills/points/etc. if the race or sex is changed or a preset is selected form the list. Modifying cosmetic details such a skin color/warpaint/hair/face shape/etc. will leave one’s points. |
| spf <name> | Save Player Face. This saves the Dragonborn’s current facial settings (from character creation) in the game files. |
| sucsm <#> | Set the speed of the free-flying camera (tfc). The default is 1. Setting it to 2, for example, would double the speed, and to 0.5 would half the speed. |
- You have to type the code without using Player.prefix for most player commands after clicking on any NPC when you are using the console window.
- addperk command is not applicable to NPCs because they rely on the perks that are assigned to them
Other
| Command | Effect |
| Addfac <FactionID> <#> | Adds the selected NPC to a faction. May cause undesired and buggy AI behavior, 1–4 affects faction rank |
| AddToFaction <FactionID> <#> | Alternate version of AddFac, adds the selected NPC to a faction. May cause undesired and buggy AI behavior, 1–4 affects faction rank |
| bat <name of text file> | Executes a .bat file. For more info read this. |
| Csb | Clear Screen Blood. Removes any blood effects from the screen. |
| Fw | Force Weather. Will automatically change the current weather to the one specified. (May also vanish as with the sw command). |
| GetGlobalValue <Value> | Returns information about the given value in the game’s settings. |
| GetInCellParam <LocationID> <FormID> | Returns whether or not the specified object is in the specified cell. Ranges from 0.00–1.00, with 0.00 being not present and 1.00 being present. |
| GetPCMiscStat <MiscStat> | Returns the specified miscellaneous stat of the Dragonborn. |
| help <“Object name”> <#> | Show all console commands with descriptions. Add descriptors to search for IDs. ex: help “elven armor” 0 will show ids of all items that include “elven armor” in the name. Quotation mark is a must for items with more than one word ex: “elven armor,” <#> sets the limits for the search function, 0 = no limits; 4 = Exact. |
| Killall | Kills all non-essential NPCs in the vicinity. Has the same result as killallactors. |
| load <save name> | Loads the specified save. Requires quotation marks around the name if includes spaces. |
| ModPCMiscStat <MiscStat> <#> | Modifies the specified miscellaneous stat of the player. |
| Pcb | Purge Cell Buffer. Purges interior cells the Dragonborn has recently exited, potentially allowing for a higher framerate at the cost of longer loading screens. |
| PlayerCreatePotion <ID> <ID> <ID> | Allows for potions to be created through the console. <ID> refers to the potion effect rather than the ingredient’s ID. The second and third <ID> codes are optional. |
| Prid <refID> | Sets the NPC as reference, allowing other commands to be used, good for targeting NPCs that cannot be reached/seleceted on screen or fixing quest glitches about NPCs not appearing. |
| Qqq | Quits the game without going through the menus. (May cause crash.) |
| Refine | Refreshes .ini settings (does not reset them). |
| RemoveFac <FactionID> | Removes the selected NPC from a faction. Usually used for unaligning hostile NPC from hostile factions. This may cause undesired and buggy AI behavior. |
| resetinterior <LocationID> | Resets the given cell, reverting it to its original settings. |
| save <save name> | Saves the game over an existing save with the specified name. Requires quotation marks around the name if includes spaces. |
| Saveini | Saves all current game settings to the game’s .ini files. |
| set <variable> to <#> | Sets the specified variable. |
| set playeranimalcount to <#> | 0 Clears non-humanoid followers and allows one to recruit again. |
| set playerfollowercount to <#> | 0 Clears followers and allows one to recruit again. |
| set timescale to <#> | Set the rate at which time passes (20 is the default, 1 is realtime) |
| sgtm <#> | Set Gametime Multiplier. This changes the game speed (e.g. movement, dialogue, etc.), with a higher number leading to a faster speed and a lower number leading to a lower speed. |
| Showglobalvars | Shows all game variables. |
| showmessage <ID> | Shows a message in the center of the screen with the given ID. |
| sqo | Show Quest Objectives. Gives a list of all objectives for ongoing quests. |
| sqt | Show Quest Targets. Gives a list of all targets for ongoing quests. |
| stp <#> <#> <#> <#> | Set Tint Parameters. Ranges from 0–1, with stp 0 0 0 0 creating the most vibrant display and stp 1 1 1 1 creating the most black and white display. |
| sw <WeatherID> | Set Weather. Changes the current weather to the one entered. It may vanish quickly depending on the area the Dragonborn is in, due to the area’s climate being forced. |
Movement
| Command | Effect |
| coc <CellID> | Center On Cell. Teleports the Dragonborn to the center of the cell. A list of coc codes is here. |
| cow Tamriel <X> <Y> | Center on World. Teleports the Dragonborn to the given coordinates. |
| player.moveto <NPCrefID> | Move to an NPC. Note that if the NPC is dead, the Dragonborn will be moved to the Dead Body Cleanup Cell where the NPC can be resurrected using the console command, but will need to use the coc command to return. |
Item Codes
We will discuss how to add items in this section of our guide. The command that will be used for it is:
Player.additem XXXXXXXX “###”
In which XXXXXXXX is the item code and ### corresponds to the amount you want.
The list is a bit lengthy, so it is advised to use CTRL+F to search for the item code you need.
Ungrouped but Useful Codes:
Below are items codes for miscellaneous items that may be useful in your quest, from Gold to lockpicks and crafting materials.
player.additem 0000000f 1; Gold
player.additem 0000000a 1; Lockpicks
player.additem 0006F993 1; Firewood
player.additem 0003AD68 1; Horker Tusk
player.additem 000318EC 1; Lantern
player.additem 0003AD6C 1; Mammoth Tusk
player.additem 000E3C16 1; Pickaxe
player.additem 0006BC04 1; Sabre Cat Tooth
player.additem 0001D4EC 1; Torch
player.additem 0002F2F4 1; Woodcutter’s Axe
Ore and Ingot Codes
player.additem 0005ACDB 1; Corundum Ore
player.additem 0005ACDC 1; Ebony Ore
player.additem 0005ACDE 1; Gold Ore
player.additem 00071CF3 1; Iron Ore
player.additem 0005ACE1 1; Malachite Ore
player.additem 0005ACE0 1; Moonstone Ore
player.additem 0005ACDD 1; Orichalcum Ore
player.additem 0005ACE2 1; Quicksilver Ore
player.additem 0005ACDF 1; Silver Ore
player.additem 0402B06B 1; Stalhrim
player.additem 0005AD93 1; Corundum Ingot
player.additem 000DB8A2 1; Dwarven Metal Ingot
player.additem 0005AD9D 1; Ebony Ingot
player.additem 0005AD9E 1; Gold Ingot
player.additem 0005ACE4 1; Iron Ingot
player.additem 0005ADA1 1; Malachite Ingot
player.additem 0005AD9F 1; Moonstone Ingot
player.additem 0005AD99 1; Orichalcum Ingot
player.additem 0005ADA0 1; Quicksilver Ingot
player.additem 0005ADA1 1; Refined Malachite
player.additem 0005AD9F 1; Refined Moonstone
player.additem 0005ACE3 1; Silver Ingot
player.additem 0005ACE5 1; Steel Ingot
Leather Codes
player.additem 0003AD52 1; Bear Pelt
player.additem 0003AD53 1; Cave Bear Pelt
player.additem 0003AD57 1; Chaurus Chitin
player.additem 0003AD8F 1; Cow Hide
player.additem 000D284D 1; Deer Hide
player.additem 0003AD90 1; Elk Hide
player.additem 000D4B35 1; Fox Pelt
player.additem 0003AD8E 1; Goat Hide
player.additem 0003AD93 1; Horse Hide
player.additem 0003AD75 1; Ice Wolf Pelt
player.additem 000DB5D2 1; Leather
player.additem 000800E3 1; Leather Strips
player.additem 0003AD6D 1; Sabre Cat Pelt
player.additem 0003AD6E 1; Sabre Cat Snow Pelt
player.additem 0003AD54 1; Snow Bear Pelt
player.additem 000D4BE7 1; Snow Fox Pelt
player.additem 0003AD74 1; Wolf Pelt
Gem Codes
player.additem 00063B46 1; Amethyst
player.additem 00063B47 1; Diamond
player.additem 00063B43 1; Emerald
player.additem 00063B45 1; Garnet
player.additem 00063B42 1; Ruby
player.additem 00063B44 1; Sapphire
player.additem 0006851E 1; Flawless Amethyst
player.additem 0006851F 1; Flawless Diamond
player.additem 00068520 1; Flawless Emerald
player.additem 00068521 1; Flawless Garnet
player.additem 00068522 1; Flawless Ruby
player.additem 00068523 1; Flawless Sapphire
player.additem 0009DFBB 1; Stone of Barenziah